The scans below all find different variations of Continuation Patterns.  They
are broken down into TC2000 and TOS (ThinkorSwim) sections, but otherwise are
the same scans.

All scans require a move (pre-existing trend) or run of 10% over 15 days prior
to the pause which sets the stock up for continuation.

------------------------------------------------------------------------------


TC2000:


J-hook Continuation Patterns:

(MAXC5.5 / MINC15.5 >= 1.10)  AND
 XAVGC8 > XAVGC8.5 AND
MAXC5.5 / MINC5 >= 1.02 AND
MAXC5.5 / MINC5 <= 1.1 AND
C >= (MAXC10.1 * 0.98) AND
C1 < MAXC10.1 AND
C2 < MAXC10.1 AND
(O1 < MAXC10.1) OR (O1 < MAXO10.1) AND
(O2 < MAXC10.1) OR (O2 < MAXO10.1) 


-----------------------------------------


Flag Continuation Patterns:

(MAXC5.5 / MINC15.5 >= 1.10)  AND
 XAVGC8 > XAVGC8.5 AND
( (MINC3 > MAXC10 * 0.9) OR (MINC3 > MINC10.7 * 1.03) ) AND
( (C <= MAXC3.1 * 1.005) OR (C <= MAXO3.1 * 1.005) ) AND
( (MAXH3 < MAXH6 AND 
   MAXH6 < MAXH9 AND 
   MAXH9 < MAXH12 AND 
   MINL12 > MINL20 AND 
   MINL20 > MINL30 AND
   AVGV3 < AVGV3.5 AND
   MAXV5 < MAXV5.5) OR

  (XAVGC3.5 > (XAVGC3.10 * 1.07) AND
   MAXH3.5 > (MAXH3.10 * 1.07) AND
   MAXL3.5 > (MAXL3.10 * 1.07) AND
   XAVGC3 < XAVGC3.5 AND
   AVGV3 < AVGV3.5 AND
   MAXV5 < MAXV5.5) OR

  (MAXC4 <= H4 and
   MAXH4 <= H4 and
   MINH6.4 * 1.10 < H4 and
   MINL6.4 * 1.05 < MINL4 and
   C >= XAVGC8 and
   XAVGC8 >= AVGC20 and
   AVGC20 > AVGC20.8 ) OR

  (XAVGC3.8 > XAVGC3.15 AND
   MAXH3.8 > (MAXH3.15 * 1.07) AND
   MAXL3.8 > (MAXL3.15 * 1.07) AND
   XAVGC3 < XAVGC3.8 AND
   MINL3 < MINL3.8 AND
   MAXH3 < MAXH3.8 AND
   AVGV3 < AVGV3.5 AND
   MAXV5 < MAXV5.5 )
)


-----------------------------------------


Consolidation Continuation Patterns:

(MAXC5.5 / MINC15.5 >= 1.10)  AND
 XAVGC8 > XAVGC8.5 AND
(MAXO5 - MINC5) < (C * 0.03)  AND
(MAXC5 - MINC5) < (C * 0.03) AND
(MAXC5 - MINO5) < (C * 0.03) AND
(MAXO5 - MINO5) < (C * 0.03)


-----------------------------------------


PullBack Opportunity (PBO) Continuation Patterns:

(MAXC5.5 / MINC15.5 >= 1.10)  AND
XAVGC8 > XAVGC8.5 AND
C < MAXC5.1 * 0.98 AND
C > MAXC5.1 * 0.95



==============================================================================
==============================================================================



TOS:


J-hook Continuation Patterns:

def O = open; def C = close;
def MINC5 = Lowest(close, 5);
def MAXC5 = Highest(close, 5);
def MINC15 = Lowest(close, 15);
def MINC20 = Lowest(close, 20);
def MAXC10 = Highest(close, 10);
def MAXO10 = Highest(open, 10);
def XAVGC8 = ExpAverage(close, 8);

plot TightJhook = (
(MAXC5[5] / MINC15[5] >= 1.10)  AND
 XAVGC8 > XAVGC8[5] AND
MAXC5[5] / MINC5 >= 1.02 AND
MAXC5[5] / MINC5 <= 1.1 AND
C >= (MAXC10[1] * 0.98) AND
C[1] < MAXC10[1] AND
C[2] < MAXC10[1] AND
((O[1] < MAXC10[1]) OR (O[1] < MAXO10[1])) AND
((O[2] < MAXC10[1]) OR (O[2] < MAXO10[1])) 
);


-----------------------------------------


Flag Continuation Patterns:


#        FLAG SCAN        #
def MAXH = highest(high);
def MAXL = lowest(close) ;
def MAXC = highest(close);
def H = high;     
def MINH = lowest(high);
def MINL = lowest(low);          
def C = close;
def MAXH3 = highest(high,3);
def MAXH6 = highest(high,6);
def MAXH9 =    highest(high,9);
def MAXH12 = highest(high,12);

#MINS         
def MINL12 = lowest(low,12);         
def MINL20 = lowest(low,20);         
def MINL30 = lowest(low,30);

#VOLUME             
def AVGV3 = Average(volume, 3);           
def MAXV5 = highest(volume, 20);             

def XAVGC3 = ExpAverage(close, 3);             
def MAXH4 = highest(high,4);         
def MAXL3 = lowest(low,3);     
        
def MAXC4 = highest(close,4);
def MAXC5 = Highest(close, 5);
def H4 = high[4];    
def MINC15 = Lowest(close, 15);
def MINH6 = lowest(high,6);     

def MINL4 = lowest(low,4);                       
def MINL6 = lowest(low,6);             

def XAVGC8 = ExpAverage(close, 8);        
def AVGC20 = Average(close, 20);         
def MINL3 = lowest(low,3);        



plot FlagScan =
(
    (MAXC5[5] / MINC15[5] >= 1.10)  AND
	XAVGC8 > XAVGC8[5] AND
    ( 
        (
         MAXH3 < MAXH6 
         AND    MAXH6 < MAXH9 
         AND    MAXH9 < MAXH12 
         AND    MINL12 > MINL20 
         AND    MINL20 > MINL30 
         AND    AVGV3 < AVGV3[5]
         AND    MAXV5 < MAXV5[5]
        )
    OR  
    (
        XAVGC3[5] > (XAVGC3[10] * 1.07) 
        AND   MAXH3[5] > (MAXH3[10] * 1.07) 
        AND   MAXL3[5] > (MAXL3[10] * 1.07) 
        AND   XAVGC3 < XAVGC3[5] 
        AND   AVGV3 < AVGV3[5] 
        AND   MAXV5 < MAXV5[5]
     )
    OR  
    (
        MAXC4 <= H4 
        AND   MAXH4 <= H4 
        AND   (MINH6[4] * 1.10 < H4 )
        AND   (MINL6[4] * 1.05 < MINL4 )
        AND   (C >= XAVGC8 )
        AND   XAVGC8 >= AVGC20 
        AND   (AVGC20 > AVGC20[8])
     )   
    OR  
    (
        XAVGC3[8] > XAVGC3[15] 
        AND   MAXH3[8] > (MAXH3[15] * 1.07) 
        AND   MAXL3[8] > (MAXL3[15] * 1.07) 
        AND   XAVGC3 < XAVGC3[8]
        AND   MINL3 < MINL3[8]
        AND   MAXH3 < MAXH3[8]
        AND   AVGV3 < AVGV3[5]
        AND   MAXV5 < MAXV5[5] 
    )
   ) 
 AND  (H < H[1] and H < MAXH3)

);


-----------------------------------------


Consolidation Continuation Patterns:

def C = close;
def MAXC5 = Highest(close, 5);
def MINC15 = Lowest(close, 15);
def XAVGC8 = ExpAverage(close, 8); 
def MAXO5 = Highest(open, 5);
def MINC5 = Lowest(close, 5);
def MINO5 = Lowest(open, 5);

plot Consol = (
(MAXC5[5] / MINC15[5] >= 1.10)  AND
 XAVGC8 > XAVGC8[5] AND
(MAXO5 - MINC5) < (C * 0.03)  AND
(MAXC5 - MINC5) < (C * 0.03) AND
(MAXC5 - MINO5) < (C * 0.03) AND
(MAXO5 - MINO5) < (C * 0.03)
);


-----------------------------------------


PullBack Opportunity (PBO) Continuation Patterns:

def C = close;
def MAXC5 = Highest(close, 5);
def MINC15 = Lowest(close, 15);
def XAVGC8 = ExpAverage(close, 8);

plot PBO = (
(MAXC5[5] / MINC15[5] >= 1.10)  AND
XAVGC8 > XAVGC8[5] AND
C < MAXC5[1] * 0.98 AND
C > MAXC5[1] * 0.95
);